/[qspeakers]/qspeakers.pro
ViewVC logotype

Contents of /qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 75 - (show annotations)
Sun Oct 26 01:24:10 2014 UTC (6 years, 11 months ago) by ben
File size: 2138 byte(s)
use translation (not functionnal)
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10
11 VERSION = 1.0.0
12 TARGET = qspeakers
13 TEMPLATE = app
14
15 unix: {
16 isEmpty(PREFIX):PREFIX = /usr/local
17 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
18 isEmpty(BINDIR):BINDIR = $$PREFIX/bin
19 isEmpty(DATADIR):DATADIR = $$PREFIX/share
20 }
21
22 config.input = config.h.in
23 config.output = config.h
24 QMAKE_SUBSTITUTES += config
25
26 SOURCES += main.cpp\
27 mainwindow.cpp \
28 speakerdialog.cpp \
29 speakerdb.cpp \
30 speaker.cpp \
31 importexport.cpp \
32 box.cpp \
33 sealedbox.cpp \
34 portedbox.cpp \
35 bandpassbox.cpp \
36 plot.cpp \
37 listdialog.cpp \
38 searchdialog.cpp \
39 system.cpp
40
41 HEADERS += mainwindow.h \
42 speakerdialog.h \
43 speakerdb.h \
44 speaker.h \
45 importexport.h \
46 box.h \
47 sealedbox.h \
48 portedbox.h \
49 bandpassbox.h \
50 plot.h \
51 listdialog.h \
52 searchdialog.h \
53 system.h
54
55 FORMS += mainwindow.ui \
56 speakerdialog.ui \
57 listdialog.ui \
58 searchdialog.ui
59
60 unix|win32: LIBS += -lqwt
61
62 TRANSLATIONS += \
63 qspeakers_en.ts \
64 qspeakers_fr.ts
65
66 LOCALE_DIR = locale
67
68 updateqm.input = TRANSLATIONS
69 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
70 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
71 updateqm.CONFIG += no_link target_predeps
72 QMAKE_EXTRA_COMPILERS += updateqm
73
74 unix: {
75 target.path = $$BINDIR
76 database.path = $$DATADIR/qspeakers
77 database.files = qspeakers_db.xml
78 translations.path = $$DATADIR/$${TARGET}
79 translations.files = $${LOCALE_DIR}
80 mime.path = $$DATADIR/mime/packages
81 mime.files = application-x-$${TARGET}.xml
82 desktop.path = $$DATADIR/applications
83 desktop.files = $${TARGET}.desktop
84 icon.path = $$DATADIR/pixmaps
85 icon.files = qspeakers.svg
86 INSTALLS += target \
87 database \
88 translations \
89 mime \
90 desktop \
91 icon
92 }

  ViewVC Help
Powered by ViewVC 1.1.26