/[qspeakers]/qspeakers.pro
ViewVC logotype

Contents of /qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 127 - (show annotations)
Sat Jun 25 01:07:49 2016 UTC (5 years, 3 months ago) by (unknown author)
File size: 2779 byte(s)
fix db and translation path for win32
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
10
11 VERSION = 1.0.0
12 TARGET = qspeakers
13 TEMPLATE = app
14
15 unix: {
16 INCLUDEPATH += /usr/include/qwt
17 equals(QT_MAJOR_VERSION, 4): LIBS = -L/usr/lib -lqwt
18 equals(QT_MAJOR_VERSION, 5): LIBS = -L/usr/lib -lqwt-qt5
19 isEmpty(PREFIX): PREFIX = /usr/local
20 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
21 isEmpty(DATADIR): DATADIR = $$PREFIX/share
22 }
23
24 win32: {
25 INCLUDEPATH += c:/qwt-6.1.3/include
26 LIBS += c:/qwt-6.1.3/lib/qwt.dll
27 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
28 isEmpty(BINDIR): BINDIR = $$PREFIX
29 isEmpty(DATADIR): DATADIR = $$PREFIX
30 }
31
32 config.input = config.h.in
33 config.output = config.h
34 QMAKE_SUBSTITUTES += config
35
36 SOURCES += main.cpp\
37 mainwindow.cpp \
38 speakerdialog.cpp \
39 speakerdb.cpp \
40 speaker.cpp \
41 importexport.cpp \
42 box.cpp \
43 sealedbox.cpp \
44 portedbox.cpp \
45 bandpassbox.cpp \
46 plot.cpp \
47 listdialog.cpp \
48 searchdialog.cpp \
49 system.cpp
50
51 HEADERS += mainwindow.h \
52 speakerdialog.h \
53 speakerdb.h \
54 speaker.h \
55 importexport.h \
56 box.h \
57 sealedbox.h \
58 portedbox.h \
59 bandpassbox.h \
60 plot.h \
61 listdialog.h \
62 searchdialog.h \
63 system.h
64
65 FORMS += mainwindow.ui \
66 speakerdialog.ui \
67 listdialog.ui \
68 searchdialog.ui
69
70 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
71
72 TRANSLATIONS += \
73 qspeakers_en.ts \
74 qspeakers_fr.ts
75
76 LOCALE_DIR = locale
77
78 updateqm.input = TRANSLATIONS
79 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
80 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
81 updateqm.CONFIG += no_link target_predeps
82 QMAKE_EXTRA_COMPILERS += updateqm
83
84 unix: {
85 target.path = $$BINDIR
86 database.path = $$DATADIR/qspeakers
87 database.files = qspeakers_db.xml
88 translations.path = $$DATADIR/$${TARGET}
89 translations.files = $${LOCALE_DIR}
90 mime.path = $$DATADIR/mime/packages
91 mime.files = application-x-$${TARGET}.xml
92 desktop.path = $$DATADIR/applications
93 desktop.files = $${TARGET}.desktop
94 icon.path = $$DATADIR/pixmaps
95 icon.files = qspeakers.png
96 INSTALLS += target \
97 database \
98 translations \
99 mime \
100 desktop \
101 icon
102 }
103
104 win32: {
105 target.path = $$BINDIR
106 database.path = $$DATADIR
107 database.files = qspeakers_db.xml
108 translations.path = $$DATADIR/$${TARGET}
109 translations.files = $${LOCALE_DIR}
110 RC_ICONS += qspeakers.ico
111 INSTALLS += target \
112 database \
113 translations \
114 }

  ViewVC Help
Powered by ViewVC 1.1.26