/[qspeakers]/qspeakers.pro
ViewVC logotype

Contents of /qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 180 - (show annotations)
Mon May 15 12:55:27 2017 UTC (6 weeks, 2 days ago) by (unknown author)
File size: 3166 byte(s)
fix qt4 compilation and pre-increment version number
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
10
11 VERSION = 1.0.2
12 TARGET = qspeakers
13 TEMPLATE = app
14
15 unix {
16 INCLUDEPATH += /usr/include/qwt
17 equals(QT_MAJOR_VERSION, 4): LIBS = -L/usr/lib -lqwt
18 equals(QT_MAJOR_VERSION, 5): LIBS = -L/usr/lib -lqwt-qt5
19 isEmpty(PREFIX): PREFIX = /usr/local
20 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
21 isEmpty(DATADIR): DATADIR = $$PREFIX/share
22 }
23
24 win32 {
25 INCLUDEPATH += c:/qwt-6.1.3/include
26 LIBS += c:/qwt-6.1.3/lib/qwt.dll
27 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
28 isEmpty(BINDIR): BINDIR = $$PREFIX
29 isEmpty(DATADIR): DATADIR = $$PREFIX
30 }
31
32 config.input = config.h.in
33 config.output = config.h
34 QMAKE_SUBSTITUTES += config
35
36 SOURCES += main.cpp\
37 mainwindow.cpp \
38 speakerdialog.cpp \
39 speakerdb.cpp \
40 speaker.cpp \
41 importexport.cpp \
42 box.cpp \
43 sealedbox.cpp \
44 portedbox.cpp \
45 bandpassbox.cpp \
46 plot.cpp \
47 listdialog.cpp \
48 searchdialog.cpp \
49 system.cpp
50
51 HEADERS += mainwindow.h \
52 speakerdialog.h \
53 speakerdb.h \
54 speaker.h \
55 importexport.h \
56 box.h \
57 sealedbox.h \
58 portedbox.h \
59 bandpassbox.h \
60 plot.h \
61 listdialog.h \
62 searchdialog.h \
63 system.h
64
65 FORMS += mainwindow.ui \
66 speakerdialog.ui \
67 listdialog.ui \
68 searchdialog.ui
69
70 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
71
72 TRANSLATIONS += \
73 qspeakers_en.ts \
74 qspeakers_fr.ts
75
76 LOCALE_DIR = locale
77
78 updateqm.input = TRANSLATIONS
79 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
80 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
81 updateqm.CONFIG += no_link target_predeps
82 QMAKE_EXTRA_COMPILERS += updateqm
83
84
85 unix {
86 MANPAGE = "qspeakers.1"
87 manpage.input = MANPAGE
88 manpage.output = $${MANPAGE}.gz
89 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
90 manpage.CONFIG += no_link target_predeps
91 QMAKE_EXTRA_COMPILERS += manpage
92 }
93
94 unix {
95 target.path = $$BINDIR
96 manual.path = $$DATADIR/man/man1
97 manual.files = $${MANPAGE}.gz
98 manual.CONFIG = no_check_exist
99 database.path = $$DATADIR/qspeakers
100 database.files = "qspeakers_db.xml"
101 translations.path = $$DATADIR/$${TARGET}
102 translations.files = $${LOCALE_DIR}
103 mime.path = $$DATADIR/mime/packages
104 mime.files = application-x-$${TARGET}.xml
105 desktop.path = $$DATADIR/applications
106 desktop.files = $${TARGET}.desktop
107 icon.path = $$DATADIR/pixmaps
108 icon.files = qspeakers.png
109 INSTALLS += target \
110 manual \
111 database \
112 translations \
113 mime \
114 desktop \
115 icon
116 }
117
118 win32 {
119 target.path = $$BINDIR
120 database.path = $$DATADIR
121 database.files = qspeakers_db.xml
122 translations.path = $$DATADIR/$${TARGET}
123 translations.files = $${LOCALE_DIR}
124 RC_ICONS += qspeakers.ico
125 INSTALLS += target \
126 database \
127 translations \
128 }

  ViewVC Help
Powered by ViewVC 1.1.26