/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 263 - (show annotations)
Fri Oct 9 10:02:17 2020 UTC (9 months, 3 weeks ago) by ben
File size: 3159 byte(s)
version 1.5
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml widgets printsupport charts
8
9 VERSION = 1.5
10 TARGET = qspeakers
11 TEMPLATE = app
12
13 win32-g++:HOST=__mswin
14 unix:HOST=__unix
15
16
17 win32-g++:contains(QMAKE_HOST.arch, x86_64):{
18 message("Host is 64bit")
19 }
20
21 unix {
22 isEmpty(PREFIX): PREFIX = /usr/local
23 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
24 isEmpty(DATADIR): DATADIR = $$PREFIX/share
25 }
26
27 win32-g++ {
28 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
29 isEmpty(BINDIR): BINDIR = $$PREFIX
30 isEmpty(DATADIR): DATADIR = $$PREFIX
31 }
32
33 config.input = config.h.in
34 config.output = config.h
35 QMAKE_SUBSTITUTES += config
36
37 SOURCES += main.cpp \
38 mainwindow.cpp \
39 speakerdialog.cpp \
40 speakerdb.cpp \
41 speaker.cpp \
42 importexport.cpp \
43 box.cpp \
44 sealedbox.cpp \
45 portedbox.cpp \
46 bandpassbox.cpp \
47 plot.cpp \
48 listdialog.cpp \
49 searchdialog.cpp \
50 system.cpp \
51 optimizer.cpp \
52 bandpassdialog.cpp
53
54 HEADERS += mainwindow.h \
55 speakerdialog.h \
56 speakerdb.h \
57 speaker.h \
58 importexport.h \
59 box.h \
60 sealedbox.h \
61 portedbox.h \
62 bandpassbox.h \
63 plot.h \
64 listdialog.h \
65 searchdialog.h \
66 system.h \
67 optimizer.h \
68 bandpassdialog.h \
69 undocommands.h
70
71 FORMS += mainwindow.ui \
72 speakerdialog.ui \
73 listdialog.ui \
74 searchdialog.ui \
75 bandpassdialog.ui
76
77 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
78
79 TRANSLATIONS += \
80 qspeakers_en.ts \
81 qspeakers_fr.ts
82
83 LOCALE_DIR = locale
84
85 updateqm.input = TRANSLATIONS
86 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
87 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
88 updateqm.CONFIG += no_link target_predeps
89 QMAKE_EXTRA_COMPILERS += updateqm
90
91
92 unix {
93 MANPAGE = "qspeakers.1"
94 manpage.input = MANPAGE
95 manpage.output = $${MANPAGE}.gz
96 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
97 manpage.CONFIG += no_link target_predeps
98 QMAKE_EXTRA_COMPILERS += manpage
99 }
100
101 unix {
102 target.path = $$BINDIR
103 manual.path = $$DATADIR/man/man1
104 manual.files = $${MANPAGE}.gz
105 manual.CONFIG = no_check_exist
106 database.path = $$DATADIR/qspeakers
107 database.files = "qspeakers_db.xml"
108 translations.path = $$DATADIR/$${TARGET}
109 translations.files = $${LOCALE_DIR}
110 mime.path = $$DATADIR/mime/packages
111 mime.files = application-x-$${TARGET}.xml
112 desktop.path = $$DATADIR/applications
113 desktop.files = $${TARGET}.desktop
114 icon.path = $$DATADIR/pixmaps
115 icon.files = qspeakers.png
116 INSTALLS += target \
117 manual \
118 database \
119 translations \
120 mime \
121 desktop \
122 icon
123 }
124
125 win32-g++ {
126 target.path = $$BINDIR
127 database.path = $$DATADIR
128 database.files = qspeakers_db.xml
129 translations.path = $$DATADIR/$${TARGET}
130 translations.files = $${LOCALE_DIR}
131 RC_ICONS += qspeakers.ico
132 INSTALLS += target \
133 database \
134 translations \
135 }

  ViewVC Help
Powered by ViewVC 1.1.26