/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 252 - (show annotations)
Mon Sep 21 21:59:01 2020 UTC (10 months, 1 week ago) by ben
File size: 3138 byte(s)
version 1.4, fix slot port len
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml widgets printsupport charts
8
9 VERSION = 1.4
10 TARGET = qspeakers
11 TEMPLATE = app
12
13 win32-g++:HOST=__mswin
14 unix:HOST=__unix
15
16
17 win32-g++:contains(QMAKE_HOST.arch, x86_64):{
18 message("Host is 64bit")
19 }
20
21 unix {
22 isEmpty(PREFIX): PREFIX = /usr/local
23 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
24 isEmpty(DATADIR): DATADIR = $$PREFIX/share
25 }
26
27 win32-g++ {
28 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
29 isEmpty(BINDIR): BINDIR = $$PREFIX
30 isEmpty(DATADIR): DATADIR = $$PREFIX
31 }
32
33 config.input = config.h.in
34 config.output = config.h
35 QMAKE_SUBSTITUTES += config
36
37 SOURCES += main.cpp \
38 mainwindow.cpp \
39 speakerdialog.cpp \
40 speakerdb.cpp \
41 speaker.cpp \
42 importexport.cpp \
43 box.cpp \
44 sealedbox.cpp \
45 portedbox.cpp \
46 bandpassbox.cpp \
47 plot.cpp \
48 listdialog.cpp \
49 searchdialog.cpp \
50 system.cpp \
51 optimizer.cpp \
52 bandpassdialog.cpp
53
54 HEADERS += mainwindow.h \
55 speakerdialog.h \
56 speakerdb.h \
57 speaker.h \
58 importexport.h \
59 box.h \
60 sealedbox.h \
61 portedbox.h \
62 bandpassbox.h \
63 plot.h \
64 listdialog.h \
65 searchdialog.h \
66 system.h \
67 optimizer.h \
68 bandpassdialog.h
69
70 FORMS += mainwindow.ui \
71 speakerdialog.ui \
72 listdialog.ui \
73 searchdialog.ui \
74 bandpassdialog.ui
75
76 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
77
78 TRANSLATIONS += \
79 qspeakers_en.ts \
80 qspeakers_fr.ts
81
82 LOCALE_DIR = locale
83
84 updateqm.input = TRANSLATIONS
85 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
86 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
87 updateqm.CONFIG += no_link target_predeps
88 QMAKE_EXTRA_COMPILERS += updateqm
89
90
91 unix {
92 MANPAGE = "qspeakers.1"
93 manpage.input = MANPAGE
94 manpage.output = $${MANPAGE}.gz
95 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
96 manpage.CONFIG += no_link target_predeps
97 QMAKE_EXTRA_COMPILERS += manpage
98 }
99
100 unix {
101 target.path = $$BINDIR
102 manual.path = $$DATADIR/man/man1
103 manual.files = $${MANPAGE}.gz
104 manual.CONFIG = no_check_exist
105 database.path = $$DATADIR/qspeakers
106 database.files = "qspeakers_db.xml"
107 translations.path = $$DATADIR/$${TARGET}
108 translations.files = $${LOCALE_DIR}
109 mime.path = $$DATADIR/mime/packages
110 mime.files = application-x-$${TARGET}.xml
111 desktop.path = $$DATADIR/applications
112 desktop.files = $${TARGET}.desktop
113 icon.path = $$DATADIR/pixmaps
114 icon.files = qspeakers.png
115 INSTALLS += target \
116 manual \
117 database \
118 translations \
119 mime \
120 desktop \
121 icon
122 }
123
124 win32-g++ {
125 target.path = $$BINDIR
126 database.path = $$DATADIR
127 database.files = qspeakers_db.xml
128 translations.path = $$DATADIR/$${TARGET}
129 translations.files = $${LOCALE_DIR}
130 RC_ICONS += qspeakers.ico
131 INSTALLS += target \
132 database \
133 translations \
134 }

  ViewVC Help
Powered by ViewVC 1.1.26