/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 239 - (show annotations)
Mon Dec 9 15:57:15 2019 UTC (21 months, 2 weeks ago) by ben
File size: 3012 byte(s)
crash fixes and easier spk import
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml widgets printsupport charts
8
9 VERSION = 1.2.3
10 TARGET = qspeakers
11 TEMPLATE = app
12
13 unix {
14 isEmpty(PREFIX): PREFIX = /usr/local
15 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
16 isEmpty(DATADIR): DATADIR = $$PREFIX/share
17 }
18
19 win32 {
20 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
21 isEmpty(BINDIR): BINDIR = $$PREFIX
22 isEmpty(DATADIR): DATADIR = $$PREFIX
23 }
24
25 config.input = config.h.in
26 config.output = config.h
27 QMAKE_SUBSTITUTES += config
28
29 SOURCES += main.cpp \
30 mainwindow.cpp \
31 speakerdialog.cpp \
32 speakerdb.cpp \
33 speaker.cpp \
34 importexport.cpp \
35 box.cpp \
36 sealedbox.cpp \
37 portedbox.cpp \
38 bandpassbox.cpp \
39 plot.cpp \
40 listdialog.cpp \
41 searchdialog.cpp \
42 system.cpp \
43 optimizer.cpp \
44 bandpassdialog.cpp
45
46 HEADERS += mainwindow.h \
47 speakerdialog.h \
48 speakerdb.h \
49 speaker.h \
50 importexport.h \
51 box.h \
52 sealedbox.h \
53 portedbox.h \
54 bandpassbox.h \
55 plot.h \
56 listdialog.h \
57 searchdialog.h \
58 system.h \
59 optimizer.h \
60 bandpassdialog.h
61
62 FORMS += mainwindow.ui \
63 speakerdialog.ui \
64 listdialog.ui \
65 searchdialog.ui \
66 bandpassdialog.ui
67
68 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
69
70 TRANSLATIONS += \
71 qspeakers_en.ts \
72 qspeakers_fr.ts
73
74 LOCALE_DIR = locale
75
76 updateqm.input = TRANSLATIONS
77 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
78 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
79 updateqm.CONFIG += no_link target_predeps
80 QMAKE_EXTRA_COMPILERS += updateqm
81
82
83 unix {
84 MANPAGE = "qspeakers.1"
85 manpage.input = MANPAGE
86 manpage.output = $${MANPAGE}.gz
87 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
88 manpage.CONFIG += no_link target_predeps
89 QMAKE_EXTRA_COMPILERS += manpage
90 }
91
92 unix {
93 target.path = $$BINDIR
94 manual.path = $$DATADIR/man/man1
95 manual.files = $${MANPAGE}.gz
96 manual.CONFIG = no_check_exist
97 database.path = $$DATADIR/qspeakers
98 database.files = "qspeakers_db.xml"
99 translations.path = $$DATADIR/$${TARGET}
100 translations.files = $${LOCALE_DIR}
101 mime.path = $$DATADIR/mime/packages
102 mime.files = application-x-$${TARGET}.xml
103 desktop.path = $$DATADIR/applications
104 desktop.files = $${TARGET}.desktop
105 icon.path = $$DATADIR/pixmaps
106 icon.files = qspeakers.png
107 INSTALLS += target \
108 manual \
109 database \
110 translations \
111 mime \
112 desktop \
113 icon
114 }
115
116 win32 {
117 target.path = $$BINDIR
118 database.path = $$DATADIR
119 database.files = qspeakers_db.xml
120 translations.path = $$DATADIR/$${TARGET}
121 translations.files = $${LOCALE_DIR}
122 RC_ICONS += qspeakers.ico
123 INSTALLS += target \
124 database \
125 translations \
126 }

  ViewVC Help
Powered by ViewVC 1.1.26