/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 220 - (show annotations)
Sun Mar 18 21:16:30 2018 UTC (3 years, 4 months ago) by ben
File size: 3089 byte(s)
added bandpass aligment chooser dialog
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
10 greaterThan(QT_VERSION, 5.8): QT += charts
11
12 VERSION = 1.1.0
13 TARGET = qspeakers
14 TEMPLATE = app
15
16 unix {
17 isEmpty(PREFIX): PREFIX = /usr/local
18 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
19 isEmpty(DATADIR): DATADIR = $$PREFIX/share
20 }
21
22 win32 {
23 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
24 isEmpty(BINDIR): BINDIR = $$PREFIX
25 isEmpty(DATADIR): DATADIR = $$PREFIX
26 }
27
28 config.input = config.h.in
29 config.output = config.h
30 QMAKE_SUBSTITUTES += config
31
32 SOURCES += main.cpp \
33 mainwindow.cpp \
34 speakerdialog.cpp \
35 speakerdb.cpp \
36 speaker.cpp \
37 importexport.cpp \
38 box.cpp \
39 sealedbox.cpp \
40 portedbox.cpp \
41 bandpassbox.cpp \
42 plot.cpp \
43 listdialog.cpp \
44 searchdialog.cpp \
45 system.cpp \
46 optimizer.cpp \
47 bandpassdialog.cpp
48
49 HEADERS += mainwindow.h \
50 speakerdialog.h \
51 speakerdb.h \
52 speaker.h \
53 importexport.h \
54 box.h \
55 sealedbox.h \
56 portedbox.h \
57 bandpassbox.h \
58 plot.h \
59 listdialog.h \
60 searchdialog.h \
61 system.h \
62 optimizer.h \
63 bandpassdialog.h
64
65 FORMS += mainwindow.ui \
66 speakerdialog.ui \
67 listdialog.ui \
68 searchdialog.ui \
69 bandpassdialog.ui
70
71 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
72
73 TRANSLATIONS += \
74 qspeakers_en.ts \
75 qspeakers_fr.ts
76
77 LOCALE_DIR = locale
78
79 updateqm.input = TRANSLATIONS
80 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
81 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
82 updateqm.CONFIG += no_link target_predeps
83 QMAKE_EXTRA_COMPILERS += updateqm
84
85
86 unix {
87 MANPAGE = "qspeakers.1"
88 manpage.input = MANPAGE
89 manpage.output = $${MANPAGE}.gz
90 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
91 manpage.CONFIG += no_link target_predeps
92 QMAKE_EXTRA_COMPILERS += manpage
93 }
94
95 unix {
96 target.path = $$BINDIR
97 manual.path = $$DATADIR/man/man1
98 manual.files = $${MANPAGE}.gz
99 manual.CONFIG = no_check_exist
100 database.path = $$DATADIR/qspeakers
101 database.files = "qspeakers_db.xml"
102 translations.path = $$DATADIR/$${TARGET}
103 translations.files = $${LOCALE_DIR}
104 mime.path = $$DATADIR/mime/packages
105 mime.files = application-x-$${TARGET}.xml
106 desktop.path = $$DATADIR/applications
107 desktop.files = $${TARGET}.desktop
108 icon.path = $$DATADIR/pixmaps
109 icon.files = qspeakers.png
110 INSTALLS += target \
111 manual \
112 database \
113 translations \
114 mime \
115 desktop \
116 icon
117 }
118
119 win32 {
120 target.path = $$BINDIR
121 database.path = $$DATADIR
122 database.files = qspeakers_db.xml
123 translations.path = $$DATADIR/$${TARGET}
124 translations.files = $${LOCALE_DIR}
125 RC_ICONS += qspeakers.ico
126 INSTALLS += target \
127 database \
128 translations \
129 }

  ViewVC Help
Powered by ViewVC 1.1.26