/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 219 - (show annotations)
Sun Mar 18 13:50:00 2018 UTC (3 years, 4 months ago) by ben
File size: 3017 byte(s)
refactored optimization formulae for future use with bandpass alignments
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
10 greaterThan(QT_VERSION, 5.8): QT += charts
11
12 VERSION = 1.1.0
13 TARGET = qspeakers
14 TEMPLATE = app
15
16 unix {
17 isEmpty(PREFIX): PREFIX = /usr/local
18 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
19 isEmpty(DATADIR): DATADIR = $$PREFIX/share
20 }
21
22 win32 {
23 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
24 isEmpty(BINDIR): BINDIR = $$PREFIX
25 isEmpty(DATADIR): DATADIR = $$PREFIX
26 }
27
28 config.input = config.h.in
29 config.output = config.h
30 QMAKE_SUBSTITUTES += config
31
32 SOURCES += main.cpp \
33 mainwindow.cpp \
34 speakerdialog.cpp \
35 speakerdb.cpp \
36 speaker.cpp \
37 importexport.cpp \
38 box.cpp \
39 sealedbox.cpp \
40 portedbox.cpp \
41 bandpassbox.cpp \
42 plot.cpp \
43 listdialog.cpp \
44 searchdialog.cpp \
45 system.cpp \
46 optimizer.cpp
47
48 HEADERS += mainwindow.h \
49 speakerdialog.h \
50 speakerdb.h \
51 speaker.h \
52 importexport.h \
53 box.h \
54 sealedbox.h \
55 portedbox.h \
56 bandpassbox.h \
57 plot.h \
58 listdialog.h \
59 searchdialog.h \
60 system.h \
61 optimizer.h
62
63 FORMS += mainwindow.ui \
64 speakerdialog.ui \
65 listdialog.ui \
66 searchdialog.ui
67
68 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
69
70 TRANSLATIONS += \
71 qspeakers_en.ts \
72 qspeakers_fr.ts
73
74 LOCALE_DIR = locale
75
76 updateqm.input = TRANSLATIONS
77 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
78 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
79 updateqm.CONFIG += no_link target_predeps
80 QMAKE_EXTRA_COMPILERS += updateqm
81
82
83 unix {
84 MANPAGE = "qspeakers.1"
85 manpage.input = MANPAGE
86 manpage.output = $${MANPAGE}.gz
87 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
88 manpage.CONFIG += no_link target_predeps
89 QMAKE_EXTRA_COMPILERS += manpage
90 }
91
92 unix {
93 target.path = $$BINDIR
94 manual.path = $$DATADIR/man/man1
95 manual.files = $${MANPAGE}.gz
96 manual.CONFIG = no_check_exist
97 database.path = $$DATADIR/qspeakers
98 database.files = "qspeakers_db.xml"
99 translations.path = $$DATADIR/$${TARGET}
100 translations.files = $${LOCALE_DIR}
101 mime.path = $$DATADIR/mime/packages
102 mime.files = application-x-$${TARGET}.xml
103 desktop.path = $$DATADIR/applications
104 desktop.files = $${TARGET}.desktop
105 icon.path = $$DATADIR/pixmaps
106 icon.files = qspeakers.png
107 INSTALLS += target \
108 manual \
109 database \
110 translations \
111 mime \
112 desktop \
113 icon
114 }
115
116 win32 {
117 target.path = $$BINDIR
118 database.path = $$DATADIR
119 database.files = qspeakers_db.xml
120 translations.path = $$DATADIR/$${TARGET}
121 translations.files = $${LOCALE_DIR}
122 RC_ICONS += qspeakers.ico
123 INSTALLS += target \
124 database \
125 translations \
126 }

  ViewVC Help
Powered by ViewVC 1.1.26