/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 209 - (show annotations)
Sat Sep 2 00:38:40 2017 UTC (3 years, 10 months ago) by ben
File size: 3209 byte(s)
add qtcharts first working version
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml
8
9 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
10 greaterThan(QT_VERSION, 5.8): QT += charts
11
12 VERSION = 1.0.3
13 TARGET = qspeakers
14 TEMPLATE = app
15
16 unix {
17 INCLUDEPATH += /usr/include/qwt
18 equals(QT_MAJOR_VERSION, 4): LIBS = -L/usr/lib -lqwt
19 equals(QT_MAJOR_VERSION, 5): LIBS = -L/usr/lib -lqwt-qt5
20 isEmpty(PREFIX): PREFIX = /usr/local
21 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
22 isEmpty(DATADIR): DATADIR = $$PREFIX/share
23 }
24
25 win32 {
26 INCLUDEPATH += c:/qwt-6.1.3/include
27 LIBS += c:/qwt-6.1.3/lib/qwt.dll
28 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
29 isEmpty(BINDIR): BINDIR = $$PREFIX
30 isEmpty(DATADIR): DATADIR = $$PREFIX
31 }
32
33 config.input = config.h.in
34 config.output = config.h
35 QMAKE_SUBSTITUTES += config
36
37 SOURCES += main.cpp\
38 mainwindow.cpp \
39 speakerdialog.cpp \
40 speakerdb.cpp \
41 speaker.cpp \
42 importexport.cpp \
43 box.cpp \
44 sealedbox.cpp \
45 portedbox.cpp \
46 bandpassbox.cpp \
47 plot.cpp \
48 listdialog.cpp \
49 searchdialog.cpp \
50 system.cpp
51
52 HEADERS += mainwindow.h \
53 speakerdialog.h \
54 speakerdb.h \
55 speaker.h \
56 importexport.h \
57 box.h \
58 sealedbox.h \
59 portedbox.h \
60 bandpassbox.h \
61 plot.h \
62 listdialog.h \
63 searchdialog.h \
64 system.h
65
66 FORMS += mainwindow.ui \
67 speakerdialog.ui \
68 listdialog.ui \
69 searchdialog.ui
70
71 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
72
73 TRANSLATIONS += \
74 qspeakers_en.ts \
75 qspeakers_fr.ts
76
77 LOCALE_DIR = locale
78
79 updateqm.input = TRANSLATIONS
80 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
81 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
82 updateqm.CONFIG += no_link target_predeps
83 QMAKE_EXTRA_COMPILERS += updateqm
84
85
86 unix {
87 MANPAGE = "qspeakers.1"
88 manpage.input = MANPAGE
89 manpage.output = $${MANPAGE}.gz
90 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
91 manpage.CONFIG += no_link target_predeps
92 QMAKE_EXTRA_COMPILERS += manpage
93 }
94
95 unix {
96 target.path = $$BINDIR
97 manual.path = $$DATADIR/man/man1
98 manual.files = $${MANPAGE}.gz
99 manual.CONFIG = no_check_exist
100 database.path = $$DATADIR/qspeakers
101 database.files = "qspeakers_db.xml"
102 translations.path = $$DATADIR/$${TARGET}
103 translations.files = $${LOCALE_DIR}
104 mime.path = $$DATADIR/mime/packages
105 mime.files = application-x-$${TARGET}.xml
106 desktop.path = $$DATADIR/applications
107 desktop.files = $${TARGET}.desktop
108 icon.path = $$DATADIR/pixmaps
109 icon.files = qspeakers.png
110 INSTALLS += target \
111 manual \
112 database \
113 translations \
114 mime \
115 desktop \
116 icon
117 }
118
119 win32 {
120 target.path = $$BINDIR
121 database.path = $$DATADIR
122 database.files = qspeakers_db.xml
123 translations.path = $$DATADIR/$${TARGET}
124 translations.files = $${LOCALE_DIR}
125 RC_ICONS += qspeakers.ico
126 INSTALLS += target \
127 database \
128 translations \
129 }

  ViewVC Help
Powered by ViewVC 1.1.26