/[qspeakers]/branches/qtcharts/qspeakers.pro
ViewVC logotype

Contents of /branches/qtcharts/qspeakers.pro

Parent Directory Parent Directory | Revision Log Revision Log


Revision 299 - (show annotations)
Wed Nov 25 20:05:12 2020 UTC (8 months ago) by ben
File size: 3540 byte(s)
Display SPL value
1 #-------------------------------------------------
2 #
3 # Project created by QtCreator 2014-09-23T08:12:05
4 #
5 #-------------------------------------------------
6
7 QT += core gui xml widgets printsupport charts
8 CONFIG += c++11
9 VERSION = 1.6.1
10 REVISION = $$system(svnversion|grep '[[:digit:]]' || git describe --long --tags 2>/dev/null || echo "stable")
11 TARGET = qspeakers
12 TEMPLATE = app
13
14 win32-g++:HOST=__mswin
15 unix:HOST=__unix
16
17 CONFIG(release, debug|release):DEFINES += QT_NO_DEBUG_OUTPUT
18
19 win32-g++:contains(QMAKE_HOST.arch, x86_64):{
20 message("Host is 64bit")
21 }
22
23 unix {
24 isEmpty(PREFIX): PREFIX = /usr/local
25 isEmpty(BINDIR): BINDIR = $$PREFIX/bin
26 isEmpty(DATADIR): DATADIR = $$PREFIX/share
27 }
28
29 win32-g++ {
30 isEmpty(PREFIX): PREFIX = "C:/Program Files/QSpeakers"
31 isEmpty(BINDIR): BINDIR = $$PREFIX
32 isEmpty(DATADIR): DATADIR = $$PREFIX
33 }
34
35 config.input = config.h.in
36 config.output = config.h
37 QMAKE_SUBSTITUTES += config
38
39 SOURCES += main.cpp \
40 mainwindow.cpp \
41 speakerdialog.cpp \
42 speakerdb.cpp \
43 speaker.cpp \
44 importexport.cpp \
45 box.cpp \
46 sealedbox.cpp \
47 portedbox.cpp \
48 bandpassbox.cpp \
49 plot.cpp \
50 listdialog.cpp \
51 searchdialog.cpp \
52 system.cpp \
53 optimizer.cpp \
54 bandpassdialog.cpp
55
56 HEADERS += mainwindow.h \
57 speakerdialog.h \
58 speakerdb.h \
59 speaker.h \
60 importexport.h \
61 box.h \
62 sealedbox.h \
63 portedbox.h \
64 bandpassbox.h \
65 plot.h \
66 listdialog.h \
67 searchdialog.h \
68 system.h \
69 optimizer.h \
70 bandpassdialog.h \
71 undocommands.h
72
73 FORMS += mainwindow.ui \
74 speakerdialog.ui \
75 listdialog.ui \
76 searchdialog.ui \
77 bandpassdialog.ui
78
79 isEmpty(QMAKE_LRELEASE):QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
80
81 TRANSLATIONS += \
82 qspeakers_en.ts \
83 qspeakers_fr.ts
84
85 LOCALE_DIR = locale
86
87 updateqm.input = TRANSLATIONS
88 updateqm.output = $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
89 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$LOCALE_DIR/${QMAKE_FILE_BASE}.qm
90 updateqm.CONFIG += no_link target_predeps
91 QMAKE_EXTRA_COMPILERS += updateqm
92
93
94 unix {
95 MANPAGE = "qspeakers.1"
96 manpage.input = MANPAGE
97 manpage.output = $${MANPAGE}.gz
98 manpage.commands = gzip --to-stdout ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
99 manpage.CONFIG += no_link target_predeps
100 QMAKE_EXTRA_COMPILERS += manpage
101 }
102
103 translations.files = $${LOCALE_DIR}
104 database.files = "qspeakers_db.xml"
105 scad.files = sealedbox_template.scad portedbox_template.scad bandpassbox_template.scad \
106 sealedbox_cutting_template.scad portedbox_cutting_template.scad bandpassbox_cutting_template.scad
107
108 unix {
109 target.path = $$BINDIR
110 manual.path = $$DATADIR/man/man1
111 manual.files = $${MANPAGE}.gz
112 manual.CONFIG = no_check_exist
113 database.path = $$DATADIR/qspeakers
114 translations.path = $$DATADIR/$${TARGET}
115 mime.path = $$DATADIR/mime/packages
116 mime.files = application-x-$${TARGET}.xml
117 desktop.path = $$DATADIR/applications
118 desktop.files = $${TARGET}.desktop
119 icon.path = $$DATADIR/pixmaps
120 icon.files = qspeakers.png
121 scad.path = $$DATADIR/$${TARGET}
122 INSTALLS += target \
123 icon \
124 manual \
125 database \
126 translations \
127 mime \
128 desktop \
129 scad
130 }
131
132 win32-g++ {
133 target.path = $$BINDIR
134 database.path = $$DATADIR
135 translations.path = $$DATADIR/$${TARGET}
136 scad.path = $$DATADIR/$${TARGET}
137 RC_ICONS += qspeakers.ico
138 INSTALLS += target \
139 database \
140 translations \
141 scad
142 }

  ViewVC Help
Powered by ViewVC 1.1.26